NixOS-Config/flake.nix

{
  description = "NixOS configuration for Lillian Violet's systems";

  inputs = {
    # Nixpkgs
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    nixpkgs-edge.url = "nixpkgs/master"; # Only used for bleeding edge packages

    nixos-hardware.url = "github:NixOS/nixos-hardware/master";

    # Disko for declaratively setting disk formatting
    disko.url = "github:nix-community/disko";
    disko.inputs.nixpkgs.follows = "nixpkgs";

    bcachefs-tools = {
      url = "github:koverstreet/bcachefs-tools";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-parts.follows = "flake-parts";
    };

    flake-parts = {
      url = "github:hercules-ci/flake-parts"; # Flake parts for easy flake management
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };

    # Nixos generators for creating ISOs
    nixos-generators = {
      url = "github:nix-community/nixos-generators";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # catpuccin theme
    catppuccin.url = "github:catppuccin/nix";

    # Conduit fork without all the fuss and drama
    # conduwuit = {
    #   url = "github:girlbossceo/conduwuit";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };

    # Nix index database files
    nix-index-database.url = "github:nix-community/nix-index-database";
    nix-index-database.inputs.nixpkgs.follows = "nixpkgs";

    # Secret management with sops
    sops-nix.url = "github:Mic92/sops-nix";

    # Simple mail server
    simple-nixos-mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver/master";

    # Extra utils for flakes
    flake-utils.url = "github:numtide/flake-utils";

    # Manage KDE plasma desktop configuration
    plasma-manager.url = "github:pjones/plasma-manager";
    plasma-manager.inputs.nixpkgs.follows = "nixpkgs";
    plasma-manager.inputs.home-manager.follows = "home-manager";

    # You can access packages and modules from different nixpkgs revs
    # at the same time. Here's an working example:
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
    # Also see the 'unstable-packages' overlay at 'overlays/default.nix'.

    # Lanzaboot (secure boot)
    lanzaboote.url = "github:nix-community/lanzaboote";

    # Jovian nixos (steam deck)
    jovian.url = "github:Jovian-Experiments/Jovian-NixOS";

    # Home manager
    home-manager.url = "github:nix-community/home-manager/master";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    zjstatus.url = "github:dj95/zjstatus";

    # Fix for steam cursor not being visible under wayland

    # Add any other flake you might need
    # hardware.url = "github:nixos/nixos-hardware";
    # Stylix theming engine
    stylix.url = "github:danth/stylix";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    nixpkgs-edge,
    nixos-generators,
    catppuccin,
    disko,
    home-manager,
    sops-nix,
    simple-nixos-mailserver,
    plasma-manager,
    zjstatus,
    lanzaboote,
    jovian,
    nixos-hardware,
    nix-index-database,
    # conduwuit,
    stylix,
    ...
  } @ inputs: let
    inherit (self) outputs;
    inherit (inputs) nixpkgs-edge;
    # Supported systems for your flake packages, shell, etc.
    systems = [
      "x86_64-linux"
      "aarch64-linux"
    ];
    # This is a function that generates an attribute by calling a function you
    # pass to it, with each system as an argument
    forAllSystems = nixpkgs.lib.genAttrs systems;
    pkgs-edge = import nixpkgs-edge {
      system = "x86_64-linux";
      config = {
        allowUnfree = true;
        allowUnfreePredicate = _: true;
      };
    };

    sharedModules = [
      ./nixos/shared
      sops-nix.nixosModules.sops
      disko.nixosModules.disko
      home-manager.nixosModules.home-manager
      catppuccin.nixosModules.catppuccin
      stylix.nixosModules.stylix
      nix-index-database.nixosModules.nix-index
      {
        home-manager.sharedModules = [
          inputs.catppuccin.homeManagerModules.catppuccin
          ./home-manager/shared
        ];
      }
    ];

    desktopModules = [
      ./nixos/desktop
      {
        home-manager.sharedModules = [
          inputs.plasma-manager.homeManagerModules.plasma-manager
          ./home-manager/desktop
        ];
      }
    ];
  in {
    # Your custom packages
    # Accessible through 'nix build', 'nix shell', etc
    packages = forAllSystems (system:
      import ./pkgs (import nixpkgs {
        inherit system;
        config.allowUnfree = true;
      }));
    # Formatter for your nix files, available through 'nix fmt'
    # Other options beside 'alejandra' include 'nixpkgs-fmt'
    formatter = forAllSystems (system: nixpkgs.legacyPackages.${system}.alejandra);

    # Reusable nixos modules you might want to export
    # These are usually stuff you would upstream into nixpkgs
    nixosModules = import ./modules/nixos;
    # Reusable home-manager modules you might want to export
    # These are usually stuff you would upstream into home-manager
    homeManagerModules = import ./modules/home-manager;

    # Your custom packages and modifications, exported as overlays
    overlays = import ./overlays {inherit inputs;};

    # NixOS configuration entrypoint
    # Available through 'nixos-rebuild --flake .#your-hostname'
    nixosConfigurations = {
      EDI = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {inherit inputs outputs;};
        modules =
          sharedModules
          ++ desktopModules
          ++ [
            {_module.args = {inherit pkgs-edge;};}
            nixos-hardware.nixosModules.dell-xps-13-7390
            lanzaboote.nixosModules.lanzaboote
            # > Our main nixos configuration file <
            ./nixos/hosts/EDI/configuration.nix
          ];
      };

      GLaDOS = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {inherit inputs outputs;};
        modules =
          sharedModules
          ++ desktopModules
          ++ [
            {_module.args = {inherit pkgs-edge;};}
            # > Our main nixos configuration file <
            ./nixos/hosts/GLaDOS/configuration.nix
          ];
      };

      queen = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {inherit inputs outputs;};
        modules =
          sharedModules
          ++ [
            {_module.args = {inherit pkgs-edge;};}
            simple-nixos-mailserver.nixosModule
            # > Our main nixos configuration file <
            ./nixos/hosts/queen/configuration.nix
          ];
      };

      shodan = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {inherit inputs outputs;};
        modules =
          sharedModules
          ++ [
            {_module.args = {inherit pkgs-edge;};}
            # > Our main nixos configuration file <
            ./nixos/hosts/shodan/configuration.nix
            lanzaboote.nixosModules.lanzaboote
            jovian.nixosModules.jovian
            {
              home-manager.sharedModules = [
                inputs.plasma-manager.homeManagerModules.plasma-manager
              ];
            }
          ];
      };

      wheatley = nixpkgs.lib.nixosSystem {
        system = "aarch64-linux";
        specialArgs = {inherit inputs outputs;};
        modules =
          sharedModules
          ++ [
            ./nixos/hosts/wheatley/configuration.nix
          ];
      };
    };
  };
}