NixOS-Config/nixos/hosts/GLaDOS/configuration.nix

# This is your system's configuration file.
# Use this to configure your system environment (it replaces /etc/nixos/configuration.nix)
{
  inputs,
  outputs,
  pkgs,
  ...
}: {
  # You can import other NixOS modules here
  imports = [
    # Import home-manager's NixOS module
    inputs.home-manager.nixosModules.home-manager
    outputs.nixosModules.vpn-ip
    # If you want to use modules your own flake exports (from modules/nixos):
    # outputs.nixosModules.example

    # Or modules from other flakes (such as nixos-hardware):
    # inputs.hardware.nixosModules.common-cpu-amd
    # inputs.hardware.nixosModules.common-ssd

    # You can also split up your configuration and import pieces of it here:
    # ./users.nix

    ../../desktop

    ../../../disko/GLaDOS

    # Import your generated (nixos-generate-config) hardware configuration
    ./hardware-configuration.nix
  ];

  environment.systemPackages = with pkgs; [
    gparted
  ];

  services.displayManager.plasma-login-manager = {
    enable = true;
  };

  services.displayManager.defaultSession = "plasma";
  services.desktopManager.plasma6.enable = true;

  services.vpn-ip = {
    ip = "2";
  };

  networking.hostName = "GLaDOS";

  services.xserver.videoDrivers = ["amdgpu"];
  programs = {
    steam = {
      enable = true;
      remotePlay.openFirewall = true; # Open ports in the firewall for Steam Remote Play
      dedicatedServer.openFirewall = true; # Open ports in the firewall for Source Dedicated Server
      extest.enable = true;
    };

    # gamemode.enable = false;
    # gamemode.settings = {
    #   general = {
    #     renice = 10;
    #   };

    #   # Warning: GPU optimisations have the potential to damage hardware
    #   # gpu = {
    #   #   apply_gpu_optimisations = "accept-responsibility";
    #   #   gpu_device = 0;
    #   #   amd_performance_level = "high";
    #   # };

    #   custom = {
    #     start = "${pkgs.libnotify}/bin/notify-send 'GameMode started'";
    #     end = "${pkgs.libnotify}/bin/notify-send 'GameMode ended'";
    #   };
    # };
  };
  boot = {
    initrd.systemd.services.rollback = {
      description = "Rollback BTRFS root subvolume to a pristine state";
      unitConfig.DefaultDependencies = "no";
      serviceConfig.Type = "oneshot";
      wantedBy = ["initrd.target"];
      after = ["systemd-cryptsetup@nvme_crypted.service"];
      before = ["sysroot.mount"];

      script = ''
        echo "mounting btrfs volume to tmp..."
        mkdir -p /btrfs_tmp
        mount /dev/mapper/nvme_crypted /btrfs_tmp
        echo "mount successful!"

        if [[ -e /btrfs_tmp/root ]]; then
            echo "copying root to backup..."
            mkdir -p /btrfs_tmp/old_roots
            timestamp=$(date --date="@$(stat -c %Y /btrfs_tmp/root)" "+%Y-%m-%-d_%H:%M:%S")
            mv /btrfs_tmp/root "/btrfs_tmp/old_roots/$timestamp"
            echo "copy complete!"
        fi

        if [[ -e /btrfs_tmp/home ]]; then
            echo "copying home to backup..."
            mkdir -p /btrfs_tmp/old_homes
            timestamp=$(date --date="@$(stat -c %Y /btrfs_tmp/home)" "+%Y-%m-%-d_%H:%M:%S")
            mv /btrfs_tmp/home "/btrfs_tmp/old_homes/$timestamp"
            "copy complete!"
        fi


        delete_subvolume_recursively() {
            IFS=$'\n'
            for i in $(btrfs subvolume list -o "$1" | cut -f 9- -d ' '); do
                delete_subvolume_recursively "/btrfs_tmp/$i"
            done
            btrfs subvolume delete "$1"
        }

        echo "recursively deleting root subvolumes older than five days..."
        for i in $(find /btrfs_tmp/old_roots/ -maxdepth 1 -mtime +5); do
            delete_subvolume_recursively "$i"
        done
        echo "subvolumes deleted!"

        echo "recursively deleting home subvolumes older than five days..."
        for i in $(find /btrfs_tmp/old_homes/ -maxdepth 1 -mtime +5); do
            delete_subvolume_recursively "$i"
        done
        echo "subvolumes deleted!"

        echo "creating new root and home subvolumes..."
        btrfs subvolume create /btrfs_tmp/root
        btrfs subvolume create /btrfs_tmp/home
        echo "unmounting btrfs temporary mount..."
        umount /btrfs_tmp
        echo "disk clear complete!"
      '';
    };

    loader.systemd-boot.enable = false;
    initrd.systemd.enable = true;
    kernelPackages = pkgs.linuxPackages_latest;
    supportedFilesystems = ["btrfs" "bcachefs"];

    binfmt.emulatedSystems = ["aarch64-linux"];

    lanzaboote = {
      enable = true;
      pkiBundle = "/var/lib/sbctl";
    };
    extraModprobeConfig = ''
    '';
  };

  users.users.lillian.extraGroups = ["gamemode"];

  # https://nixos.wiki/wiki/FAQ/When_do_I_update_stateVersion
  system.stateVersion = "26.05";
}